CodeItBetter Programming Another VB Programming Blog

'System & API - How to get free disk space of C drive (in two ways)
Method 1:
 
Private Declare Function GetDiskFreeSpaceEx Lib "kernel32" Alias "GetDiskFreeSpaceExA" _
    (ByVal lpDirectoryName As String, lpFreeBytesAvailable As Currency, _
    lpTotalNumberOfBytes As Currency, lpTotalNumberOfFreeBytes As Currency) As Long
 
Private Function DetermineFreeSpace(strDrive As String) As Double
    Dim BytesFree As Currency, TotBytes As Currency, TotFreeBytes As Currency
    Call GetDiskFreeSpaceEx(strDrive, BytesFree, TotBytes, TotFreeBytes)
    DetermineFreeSpace = (BytesFree * 10000) / 1024 ^ 3
End Function
 
Private Sub Command1_Click()
    MsgBox "Free space : " & Format(CStr(DetermineFreeSpace("C:")), "##0.0") & " GB"
End Sub
 
Method 2:
 
Public Sub CalculateFreeSpace()
    Dim oFSO As Object
    Dim oDrive As Object
 
    Set oFSO = CreateObject("Scripting.FileSystemObject")
    Set oDrive = oFSO.GetDrive("C:")
 
    If oDrive.IsReady Then
        MsgBox "Free space: " & ConvertFreeSpace(oDrive.FreeSpace)
    Else
        MsgBox "Free space: <drive unavailable>"
    End If
 
    Set oDrive = Nothing
    Set oFSO = Nothing
End Sub
 
Private Function ConvertFreeSpace(ByVal cFreeSpace As Currency) As String
    Select Case cFreeSpace
        Case Is < 1024
            ConvertFreeSpace = cFreeSpace & " bytes"
        Case Is < 1024 ^ 2
            ConvertFreeSpace = FormatNumber(cFreeSpace / 1024, 2) & " KB"
        Case Is < 1024 ^ 3
            ConvertFreeSpace = FormatNumber(cFreeSpace / 1024 ^ 2, 2) & " MB"
        Case Else
            ConvertFreeSpace = FormatNumber(cFreeSpace / 1024 ^ 3, 2) & " GB"
    End Select
End Function