CodeItBetter Programming Another VB Programming Blog

'System & API - How to Create a temporary file
Option Explicit
 
Private Declare Function GetTempFileName Lib "kernel32" Alias "GetTempFileNameA" _
    (ByVal lpszPath As String, ByVal lpPrefixString As String, ByVal wUnique As Long, _
    ByVal lpTempFileName As String) As Long
Private Declare Function GetTempPath Lib "kernel32" Alias "GetTempPathA" _
    (ByVal nBufferLength As Long, ByVal lpBuffer As String) As Long
 
' Generate a temporary file (path)\Tow????.TMP, where (path)
' is Windows's temporary file directory and ???? is a randomly assigned unique value.
' Then display the name of the created file on the screen.
Dim temppath As String  ' receives name of temporary file path
Dim tempfile As String  ' receives name of temporary file
Dim slength As Long  ' receives length of string returned for the path
Dim lastfour As Long  ' receives hex value of the randomly assigned ????
Dim tmpFileName As String
 
Private Sub Command1_Click()
    ' Get Windows's temporary file path
    temppath = Space(255)  ' initialize the buffer to receive the path
    slength = GetTempPath(255, temppath)  ' read the path name
    temppath = Left(temppath, slength)  ' extract data from the variable

    ' Get a uniquely assigned random file
    tempfile = Space(255)  ' initialize buffer to receive the filename
    lastfour = GetTempFileName(temppath, "Tow", 0, tempfile)  ' get a unique temporary file name
    ' (Note that the file is also created for you in this case.)
    tempfile = Left(tempfile, InStr(tempfile, vbNullChar) - 1)  ' extract data from the variable
    Label1.Caption = tempfile    '"Temporary filename: " & tempfile & " has been created."
    tmpFileName = tempfile
End Sub
 
Private Sub Command2_Click()
    Label1.Caption = tempfile & " Has been deleted from your system."
    Kill tmpFileName
End Sub